!This script was created by Laura Del Tin, Februar 2006.
!It creates the ansys model of the electromechanical microresonator
!described in:
!K.Wang,A-C.Wong,C.T-C.Nguyen,"VHF Free-free beam high-Q micromechanical
!resonators",IEEE J.of Microelectromechanical system,vol.9,n.3,September 2000
!Free download at:
!http://www.eecs.umich.edu/~ctnguyen/publications.ctnguyen.htm
!Parameters names and values are also taken from the article.
!The symmetry of the device in both lenght and width direction has been 
!exploited and only one quarter of the structure has been modeled.

/filname,geo,db


!*********** geometries parameters ********************
!******************************************************

lr=17.8   ! resonator lenght in um
wr=10     ! resonator width in um
ls=18.4   ! suspending beam lenght in um
ws=1      ! suspending beam width in um
we=4.5
h=2.05    ! resonator and beams thickness in um
d=0.123   ! dimples thickness in um
gap=0.16  ! gap between actuation electrode and bottom of the resonator

ld=ws
la=3*ws

E=150e3                 ! Young Modulus 
dens=2.333 e-15         ! density kg/um3
nu=0.226                ! Poisson ratio
eps=8.854e-6            ! free-space permittivity pF/micron

Ln1=4                   ! node locations
Ln2=13.8

!********* mesh parameters *****************
!*******************************************

hdiv=4          ! number of elements along structure thickness
wrsize=0.5      ! element dimension for resonating beam (both width and lenght)
wssize=wrsize   ! element dimension for supporting beam width 
                ! (fixed to wrsize to allow for brick meshing)
lssize=0.5      ! element dimension for supporting beam (along the lenght)
delta=0.01


!*********** element material definitions *************
!******************************************************

/prep7
et,1,solid45     !8 nodes brick mechanical element 
et,2,mesh200,6   !  area meshing element
mp,ex,1,E              ! set structural material properties
mp,nuxy,1,nu         
mp,dens,1,dens
emunit,epzro,eps       ! set electromagnetic units

finish

!******************** create model ********************
!******************************************************

/prep7

BLOCK,0,-wr/2,0,h,0,-lr/2,                             !volume 8 resonator
BLOCK,-wr/2,-wr/2-ls,0,h,-ln1-ws/2,-ln1+ws/2,          !volume 2 support beam  
BLOCK,-ld/2,0,0,-d,-ln1-ws/2,-ln1+ws/2,                !volume 3 dimple
BLOCK,-ls-wr/2,-ls-wr/2-la,0,h,-ln1-la/2,-ln1+la/2,    !volume 7 anchor
BLOCK,-ls-wr/2,-ls-wr/2-la,0,-gap,-ln1-la/2,-ln1+la/2, !volume 6 bottom anchor 
vglue,all

vsel,s,,,all
vatt,1,,1
allsel



!************ mesh ******************
!************************************

MSHAPE,0,2D 
MSHKEY,1
   
lsel,s,,,11  
lsel,a,,,23  
lsel,a,,,69  
lsel,a,,,72  
lesize,all,wssize   
allsel

lsel,s,,,2   
lsel,a,,,7   
lesize,all,wrsize
allsel

type,2
AMAP,41,8,7,3,1
  
lsel,s,,,14  
lsel,a,,,19  
LESIZE,all,lssize 
allsel

lsel,s,,,38  
lsel,a,,,43  
LESIZE,all,lssize
allsel
  
lsel,s,,,24  
lsel,a,,,48  
lsel,a,,,67  
lsel,a,,,68 
LESIZE,all,wssize
allsel

lsel,s,,,26
lsel,a,,,31
lesize,all,wrsize 
allsel

amap,38,32,25,27,31

esize,,hdiv
type,2
vsweep,7
vsweep,2
vsweep,8

esize,,2
vsweep,6
vsweep,3




!************ boundary condition **************
!**********************************************

asel,s,loc,y,-gap      !define anchor component(bottom area of the anchor
                       !                    of the structure 
nsla,s,1
cm,anchor,node
allsel

nsel,s,loc,y,-d        !define dimples component (bottom area of the dimples)
cm,dimples,node
allsel

cmsel,s,anchor         ! fix all mechanics d.o.f. of anchor component
d,all,ux,0
d,all,uy,0
d,all,uz,0
allsel

nsel,s,loc,x,0      ! prescribe symmetry condition for the mechanical structure
d,all,ux,0             
allsel
nsel,s,loc,z,0
d,all,uz,0

allsel                           
nsel,s,loc,x,delta,-wr/2-delta
nsel,r,loc,y,0                     !select nodes of the resonators that will be
nsel,r,loc,z,delta,-we/2-delta     !connect to trans126 element 
cm,trans,node
allsel

! creation of trans126 element:
! the electrode will be described by nodes in component "ground" at a distance 
! -gap in y direction from the nodes trans. Minimum distance allowed between 
! the two sets is (gap-d)/10 

emtgen,'trans',,'ground','uy',-gap,(gap-d)/10,,eps 

cmsel,s,ground
d,all,volt,0
d,all,ux,0          ! constrain mechanical d.o.f. of ground node
d,all,uy,0          ! and fix potential to 0
d,all,uz,0
allsel


tip=node(0,0,0)     ! chose the node at the center of the resonator
nsel,s,,,tip

cm,outnode,node
allsel

fini