!This script has been used in the software for the Micropyros project
! http://www.imtek.uni-freiburg.de/simulation/pyros/

!*************************************************************************
!*                                                                       *
!*                       Tamara Bechtold				 *
!*	                   March 2003             			 *
!*************************************************************************
!This file performs a  thermal transient (only heating up) analisys of a 3D 
!microthruster model (igniter and chamberwafer only). 
!Possibility to use the fine mapped mesh within the
!heater, heat area of the membrane and a fuel and the coarse mapped mesh for
!the big volumes around (igniter substrate, chamber etc.)is given. For a thin
!"belt" between the two, the free mesh can be used.
!In this file a mapped meshing with a fixed ESIZE (ESIZE of 100µm) is used,
!because no big difference was observed to the mixed meshing (see Micropyros
!report from 21.02.03)
!The geometry consists out of igniter wafer, air gap wafer,chamber wafer
!and seal wafer as well as a thermal glue layer between each two wafers 

!Dimension from the center to the outer simulations edge, lchip
lchip=0.001
!Thickness of the igniter substrate, tchip
tchip=0.00035
!Thickness of tank substrate, ttank
ttank=0.001
!Thickness of seal, tseal
tseal=0.0005
!Thickness of the air gap wafer, tair
tair=0.00035
!Thickness of thermal glue between wafer parts, tglue
tglue=0.0001
!Dimension from the center to the free membrane edge, lmembrane
lmembrane=0.00075
!Thickness of SiO2 layer, tSiO2m
tSiO2m=1.4e-6
!Thickness of SiNx layer, tSiNxm
tSiNxm=6.e-7
!Thickness of heater, theat
theat=5.e-7
!Witdh of spiral heater, wheat
wheat=0.00005
!Dimension from the center to the edge of heating area, heatarea
heatarea=0.000225
!
!Element Type: 1 for high-order, 0 for low-oder
elem=0
!
!Silicon
D1=2328
C1=702
K1=100
!SiO2
D2=2270
C2=1000
K2=1.4
!SiNx
D3=2270
C3=1000
K3=49
!Polisilicon
D4=3280
C4=700
K4=100
!Fuel
D5=1526
C5=1852
K5=0.25
!Material2
D6=2370
C6=880
K6=1.35
!Air
D7=1.239
C7=1000
K7=0.025
!Glue
D8=1380
C8=1000
K8=1.4
!
!Material number for the SiO2 membrane
SiO2membrane=2
!Material number for the SiNx membrane
SiNxmembrane=3
!Material number for the resistor
meander=4
!Material number for the igniter wafer substrate
IgniterSubstrate=1
!Material number for the igniter fuel
IgniterFuel=5
!Material number for the thermal glue
ThermalGlue=8
!Material number for the chamber fuel
ChamberFuel=5
!Material number for the air gap
AirGap=7
!Material number for the substrate of the air gap wafer
AirGapSubstrate=1
!Material number for the chamber wafer
ChamberWafer=6
!Material number for the seal wafer
SealWafer=6

!Bottom
B1=2
B11=0
B12=0
!Top
B2=0
B21=0
B22=0
!Right side
B3=0
B31=0
B32=0
!Left side
B4=0
B41=0
B42=0
!Front side
B5=0
B51=0
B52=0
!Back side
B6=0
B61=0
B62=0
!
!Applied electric power in W
power=0.15

/VUP,ALL,Z
/TRLCY,VOLU,0.5

/PREP7

/VIEW, 1 ,1,2,3 !Oblique view
/TRIAD,LBOT !Axes in the bottom left
/NUMBER,1  !Numbering shown with colors only
/PNUM,MAT,1 !Atribut numbering are the material numbers
/COLOR,NUM,DGRA,1   
/COLOR,NUM,YELL,2   
/COLOR,NUM,RED,3
/COLOR,NUM,GREE,4   
/COLOR,NUM,ORAN,5   
/COLOR,NUM,BMAG,6   
/COLOR,NUM,BLAC,7   
/COLOR,NUM,BLUE,8   
/COLOR,NUM,YGRE,9   
/COLOR,NUM,BLUE,10  
/COLOR,NUM,GCYA,11 

*IF,elem,EQ,0,THEN
ET,1,SOLID70      ! 3D Thermal solid - low order element
*ELSE
ET,1,SOLID90      ! 3D Thermal solid - high order element
*ENDIF

!   Materialparameter 
MP,DENS,1,D1
MP,C,	1,C1
MP,KXX,	1,K1
!MP,RSVX,1,R1

MP,DENS,2,D2
MP,C,	2,C2
MP,KXX,	2,K2
!MP,RSVX,2,R2

MP,DENS,3,D3
MP,C,	3,C3
MP,KXX,	3,K3
!MP,RSVX,3,R3

MP,DENS,4,D4
MP,C,	4,C4
MP,KXX,	4,K4
!MP,RSVX,4,R4

MP,DENS,5,D5
MP,C,	5,C5
MP,KXX,	5,K5
!MP,RSVX,5,R5
 
MP,DENS,6,D6 
MP,C,	6,C6 
MP,KXX,	6,K6 
!MP,RSVX,6,R6 
 
MP,DENS,7,D7
MP,C,	7,C7
MP,KXX,	7,K7
!MP,RSVX,7,R7 

!   Materialparameter for the thermal glue (probably PvC or similar)
MP,DENS,8,D8 
MP,C,	8,C8
MP,KXX,	8,K8

tmemb = tSiO2m+tSiNxm

!Definition of volumina

!Igniter wafer
BLOCK,-lchip, lchip,-lchip,lchip,-tchip,0 !1.cube-chip-block
BLOCK,-lmembrane, lmembrane,-lmembrane,lmembrane,-tchip,0 !2.igniters fuel 

!first layer of glue
upperlevel= -tchip
lowerlevel=-(tchip+tglue)

BLOCK,-lchip, lchip,-lchip,lchip,upperlevel,lowerlevel !
BLOCK,-lmembrane, lmembrane,-lmembrane,lmembrane,upperlevel,lowerlevel !

!air gap wafer
upperlevel= -(tchip+tglue)
lowerlevel= -(tchip+tglue+tair)

BLOCK,-lchip, lchip,-lchip,lchip,upperlevel,lowerlevel !
BLOCK,-lmembrane, lmembrane,-lmembrane,lmembrane,upperlevel,lowerlevel !

!second layer of glue
upperlevel=-(tchip+  tglue+tair)
lowerlevel=-(tchip+2*tglue+tair)

BLOCK,-lchip, lchip,-lchip,lchip,upperlevel,lowerlevel !
BLOCK,-lmembrane, lmembrane,-lmembrane,lmembrane,upperlevel,lowerlevel !

!Chamber wafer & fuel
upperlevel=-(tchip+2*tglue+tair)
lowerlevel=-(tchip+2*tglue+tair+ttank)

BLOCK,-lchip, lchip,-lchip,lchip,upperlevel,lowerlevel !
BLOCK,-lmembrane, lmembrane,-lmembrane,lmembrane,upperlevel,lowerlevel !

!third layer of glue
upperlevel=-(tchip+2*tglue+tair+ttank)
lowerlevel=-(tchip+3*tglue+tair+ttank)

BLOCK,-lchip, lchip,-lchip,lchip,upperlevel,lowerlevel !
BLOCK,-lmembrane, lmembrane,-lmembrane,lmembrane,upperlevel,lowerlevel !

!Seal wafer
upperlevel=-(tchip+3*tglue+tair+ttank)
lowerlevel=-(tchip+3*tglue+tair+ttank+tseal)
BLOCK,-lchip, lchip,-lchip,lchip,upperlevel,lowerlevel !

!Membrane
BLOCK,-lchip,lchip,-lchip,lchip,0,tSiO2m !SiO2membrane-layer
BLOCK,-lchip,lchip,-lchip,lchip,tSiO2m,tmemb !SiNx membrane-layer
 
!Heater
BLOCK,-heatarea,heatarea,-heatarea,heatarea,tmemb,tmemb+theat !mask for the heater, from which the volums will be subtracted 
VSEL,S,LOC,Z,tmemb,tmemb+theat  
CM,temp1,VOLU !the component will be named temp1

BLOCK,-heatarea,-heatarea+wheat,-heatarea+wheat,heatarea,tmemb,tmemb+theat!9.protective-layer(1.part)
BLOCK,-heatarea+2*wheat,-heatarea+3*wheat,-heatarea,heatarea-wheat,tmemb,tmemb+theat!10.protective-layer(2.part)
BLOCK,-wheat/2,wheat/2,-heatarea+wheat,heatarea,tmemb,tmemb+theat!11.protective-layer(3.part)
BLOCK,heatarea-3*wheat,heatarea-2*wheat,-heatarea,heatarea-wheat,tmemb,tmemb+theat!12.protective-layer(4.part)
BLOCK,heatarea-wheat,heatarea,-heatarea+wheat,heatarea,tmemb,tmemb+theat!13.protective-layer(5.part)
VSEL,S,LOC,Z,tmemb,tmemb+theat 
CMSEL,U,temp1 !unselect the entity temp1
CM,temp2,VOLU !the protective layer parts to be substructed will be calledtemp2

CMSEL,S,temp1 
CMSEL,A,temp2 
VSBV,temp1,temp2,,DELE,DELE !what is left is the heater volume
VSEL,S,LOC,Z,tmemb,tmemb+theat 
CM,heater,VOLU

/SHOW,JPEG
JPEG,ORIENT,HORIZ   
/GFILE,300, 
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

VSEL,ALL 
VOVLAP,ALL !no gluing is needed
!VPLOT,ALL

!Preparation for mapped meshing

WPCSYS,-1,0 ! resets the working plane back to the global cartesian origin
WPOFFS,0,lmembrane,0

! WPROTA, THXY, THYZ, THZX ? Rotates the working plane around z,x and y axes respectively
WPROTA,0,90,0
VSEL,ALL
VSBW,ALL,,DELE!cuts all selected volumes by the working plane,volumes willbeglued, the old volums will be deleted

WPOFFS,0,0,2*lmembrane
VSEL,ALL
VSBW,ALL,,DELE

WPCSYS,-1,0 
WPOFFS,lmembrane,0,0

WPROTA,0,0,90
VSEL,ALL
VSBW,ALL,,DELE

WPOFFS,0,0,-2*lmembrane
VSEL,ALL
VSBW,ALL,,DELE

!cutting through the heater in y-direction
WPCSYS,-1,0 
WPOFFS,-4.5*wheat,0,0
WPROTA,0,0,90

*DO,k,1,10
  VSEL,ALL
  VSBW,ALL,,DELE
  WPOFFS,0,0,wheat
*ENDDO

!cutting through the heater in x-direction
WPCSYS,-1,0 
WPOFFS,0,-4.5*wheat,0
WPROTA,0,90,0

VSEL,ALL
VSBW,ALL,,DELE

WPOFFS,0,0,-wheat
VSEL,ALL
VSBW,ALL,,DELE

WPOFFS,0,0,-7*wheat
VSEL,ALL
VSBW,ALL,,DELE

WPOFFS,0,0,-wheat
VSEL,ALL
VSBW,ALL,,DELE
  
WPCSYS,-1,0  

!Creation of entities  
!The material number will be set through VATT command

! define group of volumes belonging to the heater
VSEL,S,LOC,Z,tmemb,tmemb+theat
VATT,meander,1,1
CM,heater,VOLU

! define group of volumes belonging to the SiNx membrane
VSEL,S,LOC,Z,tSiO2m,tmemb
VATT,SiNxmembrane,1,1
CM,SiNxm,VOLU

! define group of volumes belonging to the SiO2 membrane
VSEL,S,LOC,Z,0,tSiO2m
VATT,SiO2membrane,1,1
CM,SiO2m,VOLU

! define group of volumes belonging to the igniter fuel
VSEL,S,LOC,Z,0,-tchip
VSEL,R,LOC,X,-lmembrane,lmembrane
VSEL,R,LOC,Y,-lmembrane,lmembrane
VATT,IgniterFuel,1,1
CM,igniterfuel,VOLU

! define group of volumes belonging to the igniter substrate
VSEL,S,LOC,Z,0,-tchip
CMSEL,U,igniterfuel
VATT,IgniterSubstrate,1,1
CM,igniterchip,VOLU

! define group of volumes belonging to the thermal glue
VSEL,S,LOC,X,-lmembrane,lmembrane
VSEL,R,LOC,Y,-lmembrane,lmembrane
CM,temp,VOLU

VSEL,A,LOC,Z,-tchip,-(tchip+tglue)
VSEL,A,LOC,Z,-(tchip+tglue+tair),-(tchip+2*tglue+tair)
CMSEL,U,temp
VSEL,A,LOC,Z,-(tchip+2*tglue+tair+ttank),-(tchip+3*tglue+tair+ttank)
VATT,ThermalGlue,1,1
CM,glue,VOLU

! define group of volumes belonging to the chamber fuel
VSEL,S,LOC,Z,-(tchip+2*tglue+tair),-(tchip+2*tglue+tair+ttank)
VSEL,R,LOC,X,-lmembrane,lmembrane
VSEL,R,LOC,Y,-lmembrane,lmembrane
VATT,ChamberFuel,1,1
CM,chamberfuel,VOLU

! define group of volumes belonging to the air gap
VSEL,S,LOC,Z,-tchip,-(tchip+2*tglue+tair)
VSEL,R,LOC,X,-lmembrane,lmembrane
VSEL,R,LOC,Y,-lmembrane,lmembrane
VATT,AirGap,1,1
CM,airgap,VOLU

! define group of volumes belonging to the substrate of the air gap wafer
VSEL,S,LOC,Z,-(tchip+tglue),-(tchip+tglue+tair)
CMSEL,U,airgap
VATT,AirGapSubstrate,1,1
CM,airgapsubstrate,VOLU

! define group of volumes belonging to the chamber
VSEL,S,LOC,Z,-(tchip+2*tglue+tair),-(tchip+2*tglue+tair+ttank)
CMSEL,U,temp
VATT,ChamberWafer,1,1
CM,chamber,VOLU

! define group of volumes belonging to the seal wafer
VSEL,S,LOC,Z,-(tchip+3*tglue+tair+ttank),-(tchip+3*tglue+tair+ttank+tseal)
VATT,SealWafer,1,1
CM,seal,VOLU

WPCSYS,-1,0

ALLS

!Meshing

!MSHAPE,KEY,DIMENSION For elements that support multiple shapes, specifies
!the element shape to be used for meshing  
!MSHKEY, KEY ? Specifies whether free meshing or mapped meshing should be used to mesh a model

MSHKEY,1 !mapped mashing
MSHAPE,0,3D !3D mashing with hexahedral elements

!*************************************************************************
!*                                                                       *
!*                Mapped meshing for the hole domain  			 *
!*                                                                       *
!*************************************************************************

!Definition of element size for mapped meshing
ESIZE,100E-6 VSEL,ALL
VMESH,ALL

!*************************************************************************
!*                                                                       *
!*                              Mixed meshing				  *
!*                                                                       *
!*************************************************************************

!Fine mapped meshing for the heater, heat area of the membrane and a fuel 
ESIZE,50E-6
VSEL,S,LOC,Z,-tchip,tmemb+theat
VSEL,R,LOC,X,-heatarea,heatarea
VSEL,R,LOC,Y,-heatarea,heatarea
CM,mesh1,VOLU
!VMESH,ALL

!Coarse mapped meshing for the bigger outher domains
ESIZE,200E-6
VSEL,S,LOC,Z,-(tchip+tglue),tmemb+theat
VSEL,R,LOC,X,-lmembrane,lmembrane
VSEL,R,LOC,Y,-lmembrane,lmembrane
VSEL,INVE
CM,mesh3,VOLU
!VMESH,ALL

!Free meshing for the thin belt between the both mapped meshed parts
VSEL,ALL
CMSEL,U,mesh1
CMSEL,U,mesh3

ESIZE,100E-6
MSHKEY,0 !Free mashing
MSHAPE,1,3D !3D mashing with tetrahedral elements
!VMESH,ALL
!*************************************************************************

!Ploting the elements
/COLOR,OUTL,BLAC
ALLSEL
EPLOT,ALL

nsel,s,loc,y,-lchip,0 
esln,s 
/graphics,power
/COLOR,OUTL,WHIT
EPLOT,ALL

!bottom
*IF,B1,EQ,1,THEN
ASEL,S,LOC,Z,-(tchip+3*tglue+tair+ttank+tseal)
SFA,ALL,,HFLUX,B11 !Heat flux at the bottom of the chamber wafer
*ENDIF
*IF,B1,EQ,2,THEN
ASEL,S,LOC,Z,-(tchip+3*tglue+tair+ttank+tseal)
DA,ALL,TEMP,B11 !Dirichle BC at the bottom of the chamber wafer
*ENDIF
*IF,B1,EQ,3,THEN
ASEL,S,LOC,Z,-(tchip+3*tglue+tair+ttank+tseal)
SFA,ALL,,CONV,B11,B12
*ENDIF

!top
*IF,B2,EQ,1,THEN
ASEL,S,LOC,Z,tmemb+theat
SFA,ALL,,HFLUX,B21
*ENDIF
*IF,B2,EQ,2,THEN
ASEL,S,LOC,Z,tmemb+theat
DA,ALL,TEMP,B21
*ENDIF
*IF,B2,EQ,3,THEN
ASEL,S,LOC,Z,tmemb+theat
SFA,ALL,,CONV,B21,B22
*ENDIF

!right side
*IF,B3,EQ,1,THEN
ASEL,S,LOC,Y,lchip
SFA,ALL,,HFLUX,B31
*ENDIF
*IF,B3,EQ,2,THEN
ASEL,S,LOC,Y,lchip
DA,ALL,,TEMP,B31
*ENDIF
*IF,B3,EQ,3,THEN
ASEL,S,LOC,Y,lchip
SFA,ALL,,CONV,B31,B32
*ENDIF

!left side
*IF,B4,EQ,1,THEN
ASEL,S,LOC,Y,-lchip
SFA,ALL,,HFLUX,B41
*ENDIF
*IF,B4,EQ,2,THEN
ASEL,S,LOC,Y,-lchip
DA,ALL,,TEMP,B41
*ENDIF
*IF,B4,EQ,3,THEN
ASEL,S,LOC,Y,-lchip
SFA,ALL,,CONV,B41,B42
*ENDIF

!front side
*IF,B5,EQ,1,THEN
ASEL,S,LOC,X,lchip
SFA,ALL,,HFLUX,B51
*ENDIF
*IF,B5,EQ,2,THEN
ASEL,S,LOC,X,lchip
DA,ALL,,TEMP,B51
*ENDIF
*IF,B5,EQ,3,THEN
ASEL,S,LOC,X,lchip
SFA,ALL,,CONV,B51,B52
*ENDIF

!back side
*IF,B6,EQ,1,THEN
ASEL,S,LOC,X,-lchip
SFA,ALL,,HFLUX,B61
*ENDIF
*IF,B6,EQ,2,THEN
ASEL,S,LOC,X,-lchip
DA,ALL,,TEMP,B61
*ENDIF
*IF,B6,EQ,3,THEN
ASEL,S,LOC,X,-lchip
SFA,ALL,,CONV,B61,B62
*ENDIF

!Heat generation rate to be applied as BFA on teh heater volum
hgen = power/(theat*wheat*(5*wheat+4*2*heatarea))

!Heat source
CMSEL,S,heater !heater volums
BFV,ALL,HGEN,hgen

*CFOPEN, output, txt
n1 = NODE(0,0,0)
n1name = 'FuelTop'
*VWRITE,n1name,n1
(A20, F10.0)
n2 = NODE(0,0,-0.0002)
n2name = 'FT-200' 
*VWRITE,n2name,n2
(A20, F10.0)
n3 = NODE(0,0,-0.0004)
n3name = 'FT-400'
*VWRITE,n3name,n3
(A20, F10.0)
n4 = NODE(0,0,-0.0019)
n4name ='FuelBot' 
*VWRITE,n4name,n4
(A20, F10.0)
*CFCLOS

nsel,s,,,n1
nsel,a,,,n2
nsel,a,,,n3
nsel,a,,,n4
cm,out,node

allsel                                                          
SAVE

FINISH